Что-то я торможу... Какая хитрость при установке параметров в управляемом приложении?

&НаСервере
Процедура УстановитьПараметры()
   Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("Рубль").Значение = Справочники.Валюты.НайтиПоКоду(643);
   Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ВидЦены").Значение = Справочники.ВидыЦен.НайтиПоНаименованию("Розничная",Истина);
КонецПроцедуры

наверно ты хочешь параметры в настройках пользователя установить

А кто использование и видсравнения будет указывать?

ЗначениеПараметра = КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("НачалоПериода");
ЗначениеПараметра.Значение = НачалоДня(ДатаНач);
ЗначениеПараметра.Использование = Истина;

(1) хочу что бы по-умолчанию для всех вариантов-настроек и т.п. проставлялись параметры (они фиксированные и пользователь их менять не может), понимаю что теперь это не просто ) поэтому спрашиваю... К сожалению, элементы не предопределенные.

так и устанавливай фиксированные настройки

или делай недоступные параметры

(2,3) использование я в интерфейсе проставил, в компоновке, но не суть. Так тоже не работает:

&НаСервере
Процедура УстановитьПараметры()
   Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("Рубль").Значение = Справочники.Валюты.НайтиПоКоду(643);
   Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("Рубль").Использование = Истина;
   Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ВидЦены").Значение = Справочники.ВидыЦен.НайтиПоНаименованию("Розничная",Истина);
   Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ВидЦены").Использование = Истина;
КонецПроцедуры

вид сравнения, в параметрах, ага )

ТипЗнч(Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("Рубль").Значение) какой?

(5) Так тоже нет..

&НаСервере
Процедура УстановитьПараметры()
   Отчет.КомпоновщикНастроек.ФиксированныеНастройки.ПараметрыДанных.Элементы.Найти("Рубль").Значение = Справочники.Валюты.НайтиПоКоду(643);
   Отчет.КомпоновщикНастроек.ФиксированныеНастройки.ПараметрыДанных.Элементы.Найти("ВидЦены").Значение = Справочники.ВидыЦен.НайтиПоНаименованию("Розничная",Истина);
КонецПроцедуры

(9) А использование?
И вообще есть метод УстановитьЗначениеПараметра

(8) ТипЗнч(Отчет.КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти("Рубль").Значение) = Тип("СправочникСсылка.Валюты")    Истина    Булево

Модуль ТиповыеОтчеты

Функция УстановитьПараметр(КомпоновщикНастроекКоллекцияЗначений, ИмяПараметра, Значение, Использование = Истина) Экспорт
   
   Если ТипЗнч(КомпоновщикНастроекКоллекцияЗначений) = Тип("КомпоновщикНастроекКомпоновкиДанных") Тогда
       ЗначениеПараметра = КомпоновщикНастроекКоллекцияЗначений.Настройки.ПараметрыДанных.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных(ИмяПараметра));
   ИначеЕсли ТипЗнч(КомпоновщикНастроекКоллекцияЗначений) = Тип("КоллекцияЗначенийПараметровКомпоновкиДанных") Тогда
       ЗначениеПараметра = КомпоновщикНастроекКоллекцияЗначений.Найти(ИмяПараметра);
   ИначеЕсли ТипЗнч(КомпоновщикНастроекКоллекцияЗначений) = Тип("ОформлениеКомпоновкиДанных") Тогда
       ЗначениеПараметра = КомпоновщикНастроекКоллекцияЗначений.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных(ИмяПараметра));
   КонецЕсли;
   
   Если ЗначениеПараметра = Неопределено Тогда
       Возврат Неопределено;
   Иначе
       ЗначениеПараметра.Использование = Использование;
       ЗначениеПараметра.Значение      = Значение;
       Возврат ЗначениеПараметра;
   КонецЕсли;
   
КонецФункции

(10) знаю.. просто это 100500-й вариант..
Так тоже нет.

&НаСервере
Процедура УстановитьПараметры()
   Отчет.КомпоновщикНастроек.ФиксированныеНастройки.ПараметрыДанных.УстановитьЗначениеПараметра(Новый ПараметрКомпоновкиДанных("Рубль"),Справочники.Валюты.НайтиПоКоду(643));
   Отчет.КомпоновщикНастроек.ФиксированныеНастройки.ПараметрыДанных.УстановитьЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ВидЦены"),Справочники.ВидыЦен.НайтиПоНаименованию("Розничная",Истина));
КонецПроцедуры

Я может где-то не в тот момент пытаюсь заполнить?
Вот точно такой же вопрос v8: установить значение параметра в скд
но в моем случае вызов в ОбработкаПроверкиЗаполненияНаСервере не помогает..

И если писать в фиксированные настройки, то вот такая ошибка при формировании:

Невозможно применить фиксированные настройки. Совпадают значения параметра.

посмотри что у тебя происходит в ПриЗагрузкеВариантаОтчета и в ПриЗагрузкеПользовательскихНастроек

(16) Точно! Все дело в вариантах..
Вот так правильно:
&НаСервере
Процедура ПередЗагрузкойВариантаНаСервере(Настройки)
   Настройки.ПараметрыДанных.УстановитьЗначениеПараметра(Новый ПараметрКомпоновкиДанных("Рубль"),Справочники.Валюты.НайтиПоКоду(643));
   Настройки.ПараметрыДанных.УстановитьЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ВидЦены"),Справочники.ВидыЦен.НайтиПоНаименованию("Розничная",Истина));
КонецПроцедуры

мало того,судя по этому &НаСервере в твоей Процедура УстановитьПараметры() ты параметры устанавливал в форме. Попробуй это сделать в модуле объекта отчета