Добрый день.

Нужно написать отчет по взаиморасчетам с контрагентами, чтобы в отчет выводились по ФИФО документы движения, которые образовали конечный остаток долга на выбранную дату.

Прошу советов мудрых, как это лучше и правильней реализовать.

Пока что не знаю, как можно запросом получить таблицу с документами, в сумме сделавшими движения на определенную сумму - а именно сумму долга для каждого контрагента.

Буду рад Вашим мыслям по этому поводу.
Спасибо.

(0) взять готовый что-то не позволяет ?

вести Учет по Заказам или по Документам расчетов с контрагентами.

(2) Нет, не подходит. Так добавляем еще один разрез учета, по которому должны сходится взаиморасчеты+обязательное заполнение этой аналитики.

Если конфигурация - КА, то РН "Расчеты организации по реализации".

(3) нам нужен учет по документам но без учета по документам...

ну запили ФИФО в проведение документов оплаты и последовательность

(5) По ФИФО же!

Для 7.7 делал недавно.
Тупо выгружал в Таблицу значений и закрывал расходами первые незакрытые приходы.
Отчет работал не быстро, но работал.

(8) Ну да. 2-4 часа - это разве время? Так, баловство...

(9) Ваши предложения или так попиз..ть зашли?

(0)Курс по СКД. Дмитрий Салихов. В нем твой отчет раскрыт полностью.

примерно как в (8) делал и я. сложный но получился.

(8) То есть в ТЗ выгружались все движения регистра с отбором по измерениям?

(11) Спасибо.

(13) как-бы да, ну и потом этот результат можешь разделить на 2 таблицы, расход и приход, конечно в рамках контрагент и договоров.

*контрагента

(3) бред ибо документы расчетов в типовых конфах закрываются автоматом по ФИФО

(17) тогда вообще ничего пилить не надо

вот именно, просто нужно знать типовой функционал и кстати в типовых БП 2.0 документ расчетов как субконто является обязательным для счетов расчетов с покупателями/поставщиками

(17),(19) Бред, ибо вести взиморасчеты по документам расчетов не собираюсь.

(20) ну и запаришься считать. все пройдено давно. Будут расхождения, т.к. будешь использовать деление. Отчет будет просто монструозным и постепенно начнет выдавать бред
Казалось бы в чем сложность бухгалтеру распределить оплаты в конце дня...

только (6) тогда

(21) не нужно буху ничего распределять и уж тем более в конце дня, просто нужно соблюдать последовательность доков, а оплаты будут автоматом по ФИФО закрывать реализацию

(20) ну и пилите тогда, Шура, пилите - она золотая, блеать

Нормаль все будет. У меня по фефо так работает. Причем отсрочка в каждой реализации-поступлении.

Гребет только все до начала времен.

(23) а теперь первым января взамизачет в студию!

(10) Наши предложения - не заниматься онанизмом и использовать типовой функционал.

(27) какой взаимозачет?

(27) ну что там насчет взаимозачета? бросай бухать

(0) Делал отчет по дебиторской задолженности на заданную дату, для случая когда взаиморасчеты в УТ ведут только по заказам. Неоплаченные документы определяются по фифо, если в договоре задана острочка, то показывается просрочка в календарных днях. Идея была подсмотрена где-то на инфостарте. Мой вариант запроса:

ВЫБРАТЬ
   РасчетыСКонтрагентамиУпрОстатки.ДоговорКонтрагента.Владелец КАК Контрагент,
   РасчетыСКонтрагентамиУпрОстатки.ДоговорКонтрагента КАК ДоговорКонтрагента,
   РасчетыСКонтрагентамиУпрОстатки.Сделка КАК ЗаказПокупателя,
   РасчетыСКонтрагентамиУпрОстатки.СуммаУпрОстаток КАК Сумма,
   ЕСТЬNULL(ДоговорыКонтрагентов.ОтсрочкаПлатежаДней, 0) КАК ОтсрочкаПлатежаДней
ПОМЕСТИТЬ Долги
ИЗ
   РегистрНакопления.РасчетыСКонтрагентамиУпр.Остатки(ДОБАВИТЬКДАТЕ(КОНЕЦПЕРИОДА(&ТекущаяДата, ДЕНЬ), СЕКУНДА, 1), ) КАК РасчетыСКонтрагентамиУпрОстатки
       ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
       ПО РасчетыСКонтрагентамиУпрОстатки.ДоговорКонтрагента = ДоговорыКонтрагентов.Ссылка
ГДЕ
   РасчетыСКонтрагентамиУпрОстатки.СуммаУпрОстаток > 0
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   РасчетыСКонтрагентамиУпрОбороты.ДоговорКонтрагента.Владелец КАК Контрагент,
   РасчетыСКонтрагентамиУпрОбороты.ДоговорКонтрагента КАК ДоговорКонтрагента,
   РасчетыСКонтрагентамиУпрОбороты.Сделка КАК ЗаказПокупателя,
   РасчетыСКонтрагентамиУпрОбороты.ПериодСекунда КАК ПериодСекунда,
   РасчетыСКонтрагентамиУпрОбороты.Регистратор КАК Документ,
   РасчетыСКонтрагентамиУпрОбороты.СуммаУпрПриход КАК Сумма
ПОМЕСТИТЬ Документы
ИЗ
   РегистрНакопления.РасчетыСКонтрагентамиУпр.Обороты(
           ,
           КОНЕЦПЕРИОДА(&ТекущаяДата, ДЕНЬ),
           Авто,
           (ДоговорКонтрагента, Сделка) В
               (ВЫБРАТЬ
                   Долги.ДоговорКонтрагента,
                   Долги.ЗаказПокупателя
               ИЗ
                   Долги КАК Долги)) КАК РасчетыСКонтрагентамиУпрОбороты
ГДЕ
   РасчетыСКонтрагентамиУпрОбороты.СуммаУпрПриход > 0
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Документы.Контрагент КАК Контрагент,
   Документы.ДоговорКонтрагента КАК ДоговорКонтрагента,
   Документы.ЗаказПокупателя КАК ЗаказПокупателя,
   Документы.ПериодСекунда КАК ПериодСекунда,
   Документы.Документ КАК Документ,
   Документы.Сумма КАК Сумма,
   СУММА(Документы1.Сумма) КАК СуммаИтог
ПОМЕСТИТЬ ДокументыСНарастающимИтогом
ИЗ
   Документы КАК Документы
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документы КАК Документы1
       ПО Документы.ЗаказПокупателя = Документы1.ЗаказПокупателя
           И Документы.Контрагент = Документы1.Контрагент
           И Документы.ДоговорКонтрагента = Документы1.ДоговорКонтрагента
           И (ВЫБОР
               КОГДА Документы.ПериодСекунда = Документы1.ПериодСекунда
                   ТОГДА Документы.Документ <= Документы1.Документ
               ИНАЧЕ Документы.ПериодСекунда < Документы1.ПериодСекунда
           КОНЕЦ)

СГРУППИРОВАТЬ ПО
   Документы.Контрагент,
   Документы.Документ,
   Документы.ДоговорКонтрагента,
   Документы.ЗаказПокупателя,
   Документы.ПериодСекунда,
   Документы.Сумма
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВложенныйЗапрос.Контрагент КАК Контрагент,
   ВложенныйЗапрос.ДоговорКонтрагента КАК ДоговорКонтрагента,
   ВложенныйЗапрос.ЗаказПокупателя КАК ЗаказПокупателя,
   ВложенныйЗапрос.Документ КАК Документ,
   ВложенныйЗапрос.СуммаДокумента КАК СуммаДокумента,
   ВложенныйЗапрос.ДолгПоДокументу КАК ДолгПоДокументу,
   ВложенныйЗапрос.ОтсрочкаПлатежаДней КАК ОтсрочкаПлатежаДней,
   ВложенныйЗапрос.СрокОплаты КАК СрокОплаты,
   РАЗНОСТЬДАТ(ВложенныйЗапрос.СрокОплаты, &ТекущаяДата, ДЕНЬ) КАК ПросрочкаДней
ИЗ
   (ВЫБРАТЬ
       ДокументыСНарастающимИтогом.Контрагент КАК Контрагент,
       ДокументыСНарастающимИтогом.ДоговорКонтрагента КАК ДоговорКонтрагента,
       ДокументыСНарастающимИтогом.ЗаказПокупателя КАК ЗаказПокупателя,
       ДокументыСНарастающимИтогом.ПериодСекунда КАК ПериодСекунда,
       ДокументыСНарастающимИтогом.Документ КАК Документ,
       ДокументыСНарастающимИтогом.Сумма КАК СуммаДокумента,
       ВЫБОР
           КОГДА ДокументыСНарастающимИтогом.СуммаИтог <= Долги.Сумма
               ТОГДА ДокументыСНарастающимИтогом.Сумма
           ИНАЧЕ Долги.Сумма - (ДокументыСНарастающимИтогом.СуммаИтог - ДокументыСНарастающимИтогом.Сумма)
       КОНЕЦ КАК ДолгПоДокументу,
       НАЧАЛОПЕРИОДА(ДОБАВИТЬКДАТЕ(ДокументыСНарастающимИтогом.ПериодСекунда, ДЕНЬ, Долги.ОтсрочкаПлатежаДней), ДЕНЬ) КАК СрокОплаты,
       Долги.ОтсрочкаПлатежаДней КАК ОтсрочкаПлатежаДней
   ИЗ
       Долги КАК Долги
           ЛЕВОЕ СОЕДИНЕНИЕ ДокументыСНарастающимИтогом КАК ДокументыСНарастающимИтогом
           ПО Долги.Контрагент = ДокументыСНарастающимИтогом.Контрагент
               И Долги.ДоговорКонтрагента = ДокументыСНарастающимИтогом.ДоговорКонтрагента
               И Долги.ЗаказПокупателя = ДокументыСНарастающимИтогом.ЗаказПокупателя
   ГДЕ
       Долги.Сумма - (ДокументыСНарастающимИтогом.СуммаИтог - ДокументыСНарастающимИтогом.Сумма) > 0) КАК ВложенныйЗапрос