В обработке делаю программно формируемый макет СКД.
Для примера, для развития. Пока в обработке, помимо всего прочего.
Макет СКД простейший, выводятся поля справочника номенклатура:

Код
Артикул
Наименование
Ссылка

Поля выводятся, но нет возможности открыть ссылку на номенклатуру. Курсор жирный белый крест.
Пробовал разные примеры, пока не дошел до того что бы сделать открытие ссылки на элемент справочника номенклатура.

Нет ли какой подсказки, что бы поправить и увидеть результат?

# Область ПРОГРАММНОЕ_ФОРМИРОВАНИЕ_СКД

//
&НаКлиенте
Процедура СформироватьПервыйМакетСКД(Команда)
    СформироватьПервыйМакетСКДНаСервере(ЭтаФорма.ДанныеПервогоМакетаСКД);
    Элементы.ДанныеПервогоМакетаСКД.ОтображениеСостояния.Видимость                      = Ложь;
    Элементы.ДанныеПервогоМакетаСКД.ОтображениеСостояния.ДополнительныйРежимОтображения = ДополнительныйРежимОтображения.НеИспользовать;
    Элементы.ДанныеПервогоМакетаСКД.ТолькоПросмотр = Истина;
КонецПроцедуры
//
&НаСервере
Процедура СформироватьПервыйМакетСКДНаСервере(ТабДок)
    ОбъектОбработкаНаСервере           = РеквизитФормыВЗначение("Объект");    
    СхемаСКД                           = ОбъектОбработкаНаСервере.ПолучитьМакет("МакетСКДПервый");
    КомпоновщикНастроекДанныхОбработки = Новый КомпоновщикНастроекКомпоновкиДанных;
    КомпоновщикНастроекДанныхОбработки.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаСКД));
    КомпоновщикНастроекДанныхОбработки.ЗагрузитьНастройки(СхемаСКД.НастройкиПоУмолчанию);
    //
    КомпоновщикНастроекДанныхОбработки.ЗагрузитьПользовательскиеНастройки(Объект.КомпоновщикНастроек.ПользовательскиеНастройки);
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    Макет             = КомпоновщикМакета.Выполнить(СхемаСКД, КомпоновщикНастроекДанныхОбработки.ПолучитьНастройки());
    //
    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(Макет, , );
    //
    ТабДок.Очистить();
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ТабДок);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);
КонецПроцедуры
//

# КонецОбласти

(0) обормотчик расшифровки добавь

+(2) и в программном формировании у вас много букв нехватает

ДанныеРасшифровки             = Новый ДанныеРасшифровкиКомпоновкиДанных;

и вот тут
Макет             = КомпоновщикМакета.Выполнить(СхемаСКД, КомпоновщикНастроекДанныхОбработки.ПолучитьНастройки(),ДанныеРасшифровки);

...

ПроцессорКомпоновки.Инициализировать(Макет, ,ДанныеРасшифровки);

...

АдресХранилищаДанныхРасшифровки = ПоместитьВоВременноеХранилище(ДанныеРасшифровки, ЭтаФорма.УникальныйИдентификатор);

+(3) в ТабДоке вашем еще на форме в свойствах обормотчик события нужно добавить в События -> ОбработкаРасшифровки

(0)

Зачем секс в гамаке (внешняя обработка), если для этого есть кровать (внешний отчёт) ?

(5) Решил так сделать.
Встала задача, вот занимаюсь поиском решения.

(3) пробовал всяко, то ошибки, то начинает открывать окна с числами по двойному щелчку на поле.

Но я все буду пробовать.

(4) А в этом обработчике там что будет? Примеры я конечно видел. Но везде как то все по разному (.

(6) >А в этом обработчике там что будет?

магия 1С. каких букв туда насыпешь, то и будет

типа такого

Подробности

&НаКлиенте
Процедура ОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка, ДополнительныеПараметры)
    
    СтандартнаяОбработка = Ложь;
    СтруктураРасшифровки = ПолучитьРасшифровкуНаСервере(Расшифровка);
    
    Если СтруктураРасшифровки.Свойство("Поле") И СтруктураРасшифровки["Поле"] = "Ссылка" Тогда
        
        ПоказатьЗначение(,СтруктураРасшифровки["Значение"]);
        
    КонецЕсли;
    
КонецПроцедуры

&НаСервере
Функция ПолучитьРасшифровкуНаСервере(Расшифровка)
    
    ДанныеРасшифровки     = ПолучитьИзВременногоХранилища(АдресХранилищаДанныхРасшифровки);
    
    ПоляРасшифровки     = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0];
    
    Возврат Новый Структура("Поле,
                            |Значение",
                            ПоляРасшифровки.Поле,
                            ПоляРасшифровки.Значение);
    
КонецФункции

(6) > Встала задача

дружбы мужчин и женщин не существует, т.к. между ними что-то постоянно встаёт

(8) появилась ...

(7) буду пробовать.

(9) добавил в (3) магии

АдресХранилищаДанныхРасшифровки = ...

(10)

Ругается в этой функции


&НаСервере
Функция ПолучитьРасшифровкуНаСервере(Расшифровка)
    ДанныеРасшифровки = ПолучитьИзВременногоХранилища(АдресХранилищаДанныхРасшифровки);
    ПоляРасшифровки = ДанныеРасшифровки.Элементы[Расшифровка].ПолучитьПоля()[0];
    Возврат Новый Структура("Поле,
        |Значение",
        ПоляРасшифровки.Поле,
        ПоляРасшифровки.Значение);
КонецФункции


{ВнешняяОбработка.ПримерыКода.Форма.Форма.Форма(592,52)}: Переменная не определена (АдресХранилищаДанныхРасшифровки)
    ДанныеРасшифровки = ПолучитьИзВременногоХранилища(<<?>>АдресХранилищаДанныхРасшифровки); (Проверка: Сервер)

(11+) Реквизит формы, строка?

(10) Спасибо! Теперь ссылка на номенклатуру открывается!

(12) реквизит формы, Строка (длина 0)