&НаСервере
Функция ВыполнитьЗапрос(КодНаВыполнение, КолонкиРезультата)
	
	База = "\\Server1c77\Bases1C\BaseSQL\";
	Пользователь = "Администратор";
	Пароль = "";
	
	Соединение = Новый HTTPСоединение("192.168.1.11",8090,,,,,);
	
	Заголовки = Новый Соответствие;
	Заголовки.Вставить("Base", СтрокаВBase64(База));
	Заголовки.Вставить("User", СтрокаВBase64(Пользователь));
	Заголовки.Вставить("Password", СтрокаВBase64(Пароль));
	
	Запрос = Новый HTTPЗапрос("/eval", Заголовки);
	Запрос.УстановитьТелоИзСтроки(""+КодНаВыполнение, КодировкаТекста.UTF8, ИспользованиеByteOrderMark.НеИспользовать);
	
	Ответ = Соединение.ОтправитьДляОбработки(Запрос);
	ТекстОтвета = Ответ.ПолучитьТелоКакСтроку(КодировкаТекста.UTF8);
	
	Таблица = СтрокуВТаблицу(ТекстОтвета, КолонкиРезультата);
	
	Возврат Таблица;
	
КонецФункции

&НаСервере
Процедура ЗагрузитьКонтрагентыНаСервере()
	
	КодНаВыполнение = "
	|
	|лтзКонтрагенты = СоздатьОбъект(""ТаблицаЗначений"");
	|лтзКонтрагенты.НоваяКолонка(""Контрагент"");
	|
	|лдокПлатежка = СоздатьОбъект(""Документ.Платежка"");
	|
	|ДатаС = '01.01.2017';
	|ДатаПо = РабочаяДата();
	|
	|лдокПлатежка.ВыбратьДокументы(ДатаС, ДатаПо);
	|Пока лдокПлатежка.ПолучитьДокумент() = 1 Цикл
	|	Если лдокПлатежка.Проведен()<>1 Тогда
	|		Продолжить;
	|	КонецЕсли;
	|	лтзКонтрагенты.НоваяСтрока();
	|	лтзКонтрагенты.Контрагент = лдокПлатежка.Получатель;
	|КонецЦикла;
	|
	|лдокПриходная = СоздатьОбъект(""Документ.Приходная"");
	|лдокПриходная.ВыбратьДокументы(ДатаС, ДатаПо);
	|Пока лдокПриходная.ПолучитьДокумент() = 1 Цикл
	|	Если лдокПриходная.Проведен()<>1 Тогда
	|		Продолжить;
	|	КонецЕсли;
	|	лтзКонтрагенты.НоваяСтрока();
	|	лтзКонтрагенты.Контрагент = лдокПриходная.Поставщик;
	|КонецЦикла;
	|
	|лтзКонтрагенты.Свернуть(""Контрагент"","""");
	|
	|КоличествоКонтрагентов = лтзКонтрагенты.КоличествоСтрок();
	|лтзКонтрагенты.ВыбратьСтроки();
	|Пока лтзКонтрагенты.ПолучитьСтроку() = 1 Цикл
	|	Контрагент = лтзКонтрагенты.Контрагент;
	|   Поле(Контрагент.ИНН);
	|   Поле(Контрагент.КПП);
	|   Поле(Контрагент.Наименование);
	|   Поле(Контрагент.ЮрЛицо);
	|   Поле(Контрагент.ОсновнойСчет);
	|   Поле(Контрагент.Банк);
	|   Поле(Контрагент.БИК);
	|   Поле(Контрагент.КорСчет);
	|   Поле(Контрагент.ЮрАдрес);
	|   Поле(Контрагент.ФактАдрес);
	|   Поле(Контрагент.Телефоны);
	|   Поле(Контрагент.ДоговорНомер);
	|
	|	ДоговорДата = Контрагент.ДоговорДата;
	|	СтрокаГод = Формат(ДатаГод(ДоговорДата),""Ч(0)4"");
	|	СтрокаМесяц = Формат(ДатаМесяц(ДоговорДата),""Ч(0)2"");
	|	СтрокаЧисло = Формат(ДатаЧисло(ДоговорДата),""Ч(0)2"");
	|	ДоговорДата = """"+СтрокаГод+""-""+СтрокаМесяц+""-""+СтрокаЧисло;
	|   Поле(ДоговорДата);
	|
	|   Ввод();
	|КонецЦикла;
	|
	|";
	
	Колонки = "ИНН,КПП,Наименование,ЮрЛицо,ОсновнойСчет,Банк,БИК,КорСчет,ЮрАдрес,ФактАдрес,Телефоны,ДоговорНомер,ДоговорДата";
	Таблица = ВыполнитьЗапрос(КодНаВыполнение, Колонки);
	Для Каждого ТекСтр Из Таблица Цикл
		Сообщить("Загрузка "+ТекСтр.ИНН+" "+ТекСтр.Наименование+" "+ТекСтр.ДоговорДата);
		Элемент = СтруктураИзСтрокиТЗ(ТекСтр);
		ЗагрузитьКонтрагент(Элемент);
	КонецЦикла;
	
КонецПроцедуры