Кто работал с СКД, подскажите как программно загрузить настройку в КомпоновщикНастроек из XML-файла? При попытке использования ПрочитатьXML() выдает ошибку, что не может сериализовать такой тип данных, хотя в синтаксис-помошнике написано, что объект НастройкиКомпоновкиДанных XML-сериализуется.

еще раз

(0) а как ты их выгрузил в XML?

Как сохранять и восстанавливать настройки системы компоновки данных?
Сохранение настроек в файл может быть выполнено следующим образом (листинг 6.40):
Листинг 6.40. Сохранение настроек
Процедура СохранитьНастройки(Кнопка)

   Настройки  = ОтчетОбъект.КомпоновщикНастроек.Настройки;
   НовыйСXDTO = Новый СериализаторXDTO(ФабрикаXDTO);
   Путь = СокрЛП(Константы.ПутьДоФайлов.Получить());

   Запись = Новый ЗаписьXML;
   
   Запись.ОткрытьФайл(Путь + "\config.xml");
   Запись.ЗаписатьОбъявлениеXML();
   
   НовыйСXDTO.ЗаписатьXML(Запись, Настройки, НазначениеТипаXML.Явное, ФормаXML.Элемент);
   
   Запись.Закрыть();

КонецПроцедуры

Восстановление настроек из файла может быть выполнено следующим образом (листинг 6.41):
Листинг 6.41. Восстановление настроек
Процедура ВосстановитьНастройки(Кнопка)

   Чтение = Новый ЧтениеXML;
   НовыйСXDTO = Новый СериализаторXDTO(ФабрикаXDTO);
   Путь = СокрЛП(Константы.ПутьДоФайлов.Получить());
   
   Чтение.ОткрытьФайл(Путь + "\config.xml");
   
   Настройки = НовыйСXDTO.ПрочитатьXML(Чтение);
   
   ОтчетОбъект.КомпоновщикНастроек.ЗагрузитьНастройки(Настройки);

КонецПроцедуры

В константе ПутьДоФайлов хранится путь до файла сохраняемых (восстанавливаемых) настроек.

(с) Простые примеры разработки